Fonctions avancées de recherche
Applications Calc
Réalisé avec : OOo 2.0.3
Version 1.0 du 11/10/06
Plate-forme / Os : Toutes
Distribué par le projet fr.OpenOffice.org
fr.OpenOffice.org
Sommaire
1 Préalable ..........................................................................................................................................3
1.1 Pré requis ................................................................................................................................3
1.2 Limite de l’outil .........................................................................................................................3
2 Rappels et compléments sur la fonction recherche ..........................................................................3
2.1 Les fonctions de recherche ......................................................................................................3
2.2 Les arguments .........................................................................................................................3
2.2.a Généralités .......................................................................................................................3
2.2.b La matrice .........................................................................................................................3
2.2.c Le tri ..................................................................................................................................4
3 Éviter les messages d’erreur ............................................................................................................4
3.1 Recherche infructueuse dans une liste triée ............................................................................4
3.2 Recherche infructueuse dans une liste non triée .....................................................................5
3.2.a Problème ..........................................................................................................................5
3.2.b Test de recherche .............................................................................................................6
4 Extraire des données .......................................................................................................................6
5 Recopie de la fonction RechercheX .................................................................................................7
6 Recherche multi-critères ..................................................................................................................9
6.1 Dans une table ........................................................................................................................9
6.2 Dans différentes tables ..........................................................................................................10
6.2.a Notions de base de la fonction Indirect.
..........................................................................10
6.2.b Application multi-table .....................................................................................................11
7 Applications diverses .....................................................................................................................12
7.1 Un tri dynamique ...................................................................................................................12
7.2 Extraction dynamique ............................................................................................................12
7.3 Ventilation automatique .........................................................................................................13
8 Crédits ..........................................................................................................................................15
9 Licence ..........................................................................................................................................15
Fonctions_Avancees_Recherche.odt -
Retour au Sommaire
2 / 15
fr.OpenOffice.org
1 Préalable
Ce document traite principalement les fonctions mathématiques RechercheH et RechercheV.
Les filtre applicables aux plages données ne sont pas traitéées.
1.1 Pré-requis
Les connaissances de base des fonctions, doivent être connues. Consultez « Formules et
Fonctions) » (Formules_et_Fonctions.odt), « Extraire des données dans calque »
(Extraire_des_donnees.odt), ) pour les notions de base, l’aide en ligne si nécessaire.
1.2 Limite de l’outil
Les applications complexes ou manipulant un nombre de données importantes gagneront souvent à
être réalisées avec le module SGBD « Base », tant au niveau ergonomie que maintenance. Lorsque cela n’est pas possible, pour de petites applications ou de nombreuses autres raisons, Calc remplit parfaitement un nombre de tâches élaborées. Que ce soit pour les solutions proposées ou pour s’imprégner un peu plus de l’esprit tableur, ce fascicule s’adresse à tous les utilisateurs de Calc non débutants.
2 Rappels et compléments sur la fonction recherche
2.1 Les fonctions de recherche
Les exemples traités utilisent principalement la fonction RechercheV 1 . Selon les besoins, la fonction
RechercheH pourra être substituée. Dans le document, le terme de « fonction RechercheX » désignera indifféremment l’une ou l’autre de ces deux fonctions. À noter que la fonction
« Recherche » ne dispose pas des mêmes propriétés que les deux précédentes (en particulier la matrice doit être triée) ; elle ne sera pas traitée ici.
2.2 Les arguments
2.2.a Généralités
Selon le besoin, l’argument pourra être : une valeur ; une référence de cellules, de plages de cellules ou un nom ; une fonction plus ou moins complexe.
La fonction RechercheX pourra elle même être incluse dans une fonction, en particulier la fonction
Si. Lorsque des arguments sont répétés presque à l’identique, le copier-coller (Ctrl+C – Ctrl+V) est un gain de temps. Les espaces sont autorisés pour séparer les arguments et faciliter la lecture.
Lorsqu’ils sont complexes, les arguments peuvent d’abord être saisis sous forme de valeur, puis remplacés par une variable ou une fonction de façon à cerner une erreur. Les arguments peuvent
également être saisis ou définis dans une colonne annexe de façon à mieux les contrôler ou les modifier. Cela constituera une partie des applications.
2.2.b La matrice
Ce terme désigne une plage de cellules composée de plusieurs lignes et de plusieurs colonnes. S’il est utile pour la maintenance d’indiquer le nom des en-têtes de lignes ou de colonnes, celles-ci ne doivent jamais être incluses dans la matrice.
1 Le terme commençant par une lettre majuscule désignera ici un nom de fonction. Il est possible de saisir le nom de fonction en minuscules dans les formules.
Fonctions_Avancees_Recherche.odt -
Retour au Sommaire
3 / 15
fr.OpenOffice.org
2.2.c Le tri
La boîte de dialogue de la fonction recherche (copie partielle)
Lorsque la table de référence (la matrice) est triée, il n’est pas nécessaire de préciser cette valeur, considérée à 1 par défaut (vrai). La recherche est beaucoup plus rapide que dans le cas contraire
(recherche dichotomique 1 ). Dans le cas où la liste n’est pas triée, il convient de saisir la valeur
« faux » ou « 0 » (zéro). Appelons le mode par défaut (argument « tri » égal à « vrai ») le mode rapide et le deuxième cas de figure le mode rigoureux.
3 Éviter les messages d’erreur
3.1 Recherche infructueuse dans une liste triée
Énoncé
Avec le mode rapide, la fonction rechercheX retourne toujours un résultat. Lorsque le critère de recherche se situe entre deux données de la table matrice, c’est le premier (dans l’ordre chronologique de la liste) qui est retenu. Ceci est très pratique, et même indispensable dans de nombreux cas comme par exemple des fourchettes de dates, des limites de montants pour des remises...
Lorsqu’il s’agit de trouver la valeur exacte, il est alors nécessaire d’effectuer un contrôle.
Exemple de recherche
La formule de la cellule G15 est :
=RECHERCHEV( F15 ; F20:G23 ;2)
Le code « A4 » retourne la valeur Article 1
Le code « F9» retourne la valeur Article 4
1 La recherche dichotomique consiste à prendre le milieu de la liste, puis, selon que le résultat est trop grand ou trop petit, à recommencer en prenant la bonne moité restante. C’est le cas pour la recherche dans un dictionnaire, ou pour tester, la recherche d’un nombre choisi aléatoirement entre 1 et 100 (moins de 8 essais sont alors nécessaires). Le gain de temps est considérable pour des volumes de données très importants, il est invisible pour seulement quelques centaines de données sur une simple liste dans Calc.
Fonctions_Avancees_Recherche.odt -
Retour au Sommaire
4 / 15
fr.OpenOffice.org
Le code «="b1"» retourne la valeur Article 3, ce qui indique la fonction n’est pas sensible à la casse.
Une cellule vide en « F15 » renvoie le message d’erreur « #NA ».
Test d’égalité
Il faut tester l’égalité entre le critère de recherche et le résultat de la recherche sur la première colonne de la matrice par la formule:
=RECHERCHEV( F15 ; F20:G23 ;1)
Le code « A4 » retourne la valeur « A3 »
Le code « B1 » retourne la valeur « B1 »
Ainsi la combinaison des deux fournit :
=SI( RECHERCHEV( F15 ; F20:G23 ;1) = F15 ; RECHERCHEV( F15 ; F20:G23 ;2) ; " -- Code incorrect --" )
On obtient ainsi
et
à laquelle on peut ajouter :
=SI(ESTVIDE( F15 ) ; "-- Taper un code en F15 --";
... pour obtenir
=SI(ESTVIDE(F15) ; "-- Taper un code en F15 --"; SI(RECHERCHEV(F15;F20:G23;1)=F15;
RECHERCHEV(F15;F20:G23;2);" -- Code incorrect --"))
Remarque : dans la formule, noter que « RECHERCHEV(
F15 ; F20:G23 ;1)
»
se retrouve avec juste un changement d’indice, effectuer alors un glisser-déposer.
3.2 Recherche infructueuse dans une liste non triée
Recherche infructueuse à partir d’une table non triée
(a cause d’une formule erronée).
La figure ci-dessus illustre le résultat sur une matrice non triée avec l’utilisation de la formule décrite au paragraphe 31b.
3.2.a Problème
Considérons les données de la figure ci-dessus.
l
La formule « =RECHERCHEV(
F15 ; F20:G23 ;2; 0 ) »
fournit un résultat correct pour un code existant (noter
’ajout de l’argument final « 0 »).
Le code « A7 » retourne la valeur « Article 2 »
Le code « B2 » retourne la valeur « #NA »
Fonctions_Avancees_Recherche.odt -
Retour au Sommaire
5 / 15
fr.OpenOffice.org
3.2.b Test de recherche
Il faut tester si le résultat de recherche ne produit pas le message d’erreur « #NA » par la fonction
« estna », ce qui donne la formule :
=SI (ESTNA(RECHERCHEV( F15 ; F20:G23 ;2;0)) ; " -- Code inexistant --" ; "Bon code")
Le code « B1 » retourne le message « Bon code »,
Le code « B7 » retourne la valeur « -- Code inexistant -- ».
Il reste donc à remplacer le texte « "Bon code" » par la formule de recherche initiale (faire un glisserdéposer) pour obtenir :
=SI(ESTNA(RECHERCHEV( F15 ; F20:G23 ;2;0));"-- Code inexistant --";RECHERCHEV( F15 ; F20:G23 ;2;0))
Cette formule assure également la vérification de la cellule vide en « F15 ».
On obtient ainsi
et
Remarques (rappels) : La matrice est en général sur une autre feuille. Elle est, de préférence, nommée (sinon utiliser les références absolues). Il est possible d’insérer des lignes à l’intérieur de la matrice et de laisser des lignes disponibles dans celle-ci (les remplir, par exemple avec le code
« zzz » si la liste est triée). Lorsque la matrice doit être agrandie, ne pas oublier de mettre à jour les
éléments correspondants (nom de la plage ou références dans la formule de recherche).
L’utilisation de listes déroulantes améliore le confort d’utilisation (non traité ici).
4 Extraire des données
La partie « Base de données » de Calc effectue très bien cette fonction. On n’oubliera pas
également le pilote de données qui peut apporter une aide à ce niveau. Il s’agit ici d’une action dynamique (c’est à dire sans intervention), moins souple et moins performante qu’une intervention manuelle mais qui est transparente pour l’utilisateur, procure un gain de temps et peut éviter des erreurs de manipulation.
Énoncé de l’exemple
Il s’agit de faire la liste des personnes de service pour la semaine courante. Un liste de base contient tous les noms dans une colonne. À droite, la colonne sera cochée (avec la lettre « X » lorsque la personne est de service). La table est représentée par la plage « C2:D14 » (voir la figure suivante).
Une autre table est destinée à recevoir la liste des personnes cochées. Cette liste est représentée par la plage « M4:M15 » (le décalage est destiné à éviter une symétrie [nous dirons qu’il est dû au hasard]).
Fonctions_Avancees_Recherche.odt -
Retour au Sommaire
6 / 15
fr.OpenOffice.org
Exemple d’extraction (suivant énoncé ci-dessus).
Le texte en bleu est destiné à être masqué.
Réalisation
La méthode consiste à numéroter (de 1 à n) les noms qui sont cochés afin de les récupérer par leur numéro dans l’autre liste.
Colonne B (B3) : =SI(
D3 ="X"; B2 +1; B2 ). La formule permet d’incrémenter la ligne si la colonne D contient la lettre X (La fonction « estvide » pourrait être utilisée, mais dans la suite des exemples, elle pourra contenir une formule, ce qui ne fonctionnerait alors pas).
Colonne L (L5) : il peut s’agit d’une simple saisie incrémenté ou de la formule : =A2+1. La formule présente l’avantage d’être plus facile à recopier pour allonger un tableau.
Colonne M (M5) : =RECHERCHEV(
L5 ; $B$3:$C$14 ;2;0). On récupère ainsi le premier nom correspondant au numéro de la colonne L.
Problème lors de la recopie en M9 il n’y a pas de 5e personne, donc le message « #NA » ; d'où la formule corrigée :
=SI(ESTNA(RECHERCHEV( L5 ; $B$3:$C$14 ;2;0));"";RECHERCHEV( L5 ;$ B$3:$C$14 ;2;0))
Variante
Le numéro de ligne (colonne L) peut être remplacé par la formule LIGNE()-LIGNE($M$5)+1. (cette formule remplace
L5
). La fonction LIGNE() permet d’obtenir le numéro de la ligne sur laquelle se trouve la formule et la formule LIGNE($M$5) la valeur 5 (cellule M5) dans l’exemple, plus 1 pour commencer à 1 (car 5-5=0). La formule LIGNE()-4 fournit le même résultat mais attention en cas de déplacement de la table.
Ce principe est utilisable dans les exemples qui suivent, mais ne sera pas appliqué par souci de simplicité des formules et pour ne pas pénaliser l’utilisateur qui na maîtriserait pas cette fonction.
5 Recopie de la fonction RechercheX
Énoncé de l’exemple
Reprenons l’exemple précédent avec une ventilation par jour. En cellule « O2 » nommée « jour »
Fonctions_Avancees_Recherche.odt -
Retour au Sommaire
7 / 15
fr.OpenOffice.org
dans l’exemple, il suffit de taper le jour pour que la colonne B soit cochée selon l’indication du jour désigné. L’exemple montre en colonne C le « compteur » indiquant que cet exemple s'intègre au précédent.
Exemple énoncé-réalisation
Réalisation
Le principe est de numéroter une colonne (la colonne A) qui permet de définir la ligne à utiliser dans la table. Ceci évite de modifier la formule à chaque ligne.
Colonne B (B3) : =RECHERCHEH( jour ; $E$2:$K$14 ; A3
+1;0)
1 . Remarquer le numéro de ligne (recherche
verticale) A3+1 car la table commence en E2 (il aurait été possible, et plus logique, de commencer la numérotation en A2, mais ceci permet de connaître le nombre de personnes si la colonne A n’est pas masquée).
Remarque : Dans le cas de cette application fusionnée avec celle consistant à extraire les données
(4.2), les formules en B3 et C3 (=SI(
B3 ="X"; C2 +1; C2 )) peuvent éventuellement être réunies en C3 sous la forme : =SI(RECHERCHEH( jour ; $E$2:$K$14 ; A3 +1;0)="X"; C2 +1; C2 ) (la référence « B3 » est remplacée par la formule de recherche). Il s’agit là plus d’une satisfaction intellectuelle que d’un avantage car la conception, la vérification et la maintenance s’en trouvent pénalisées. Par contre, cela permet de se familiariser avec des formules complexes.
Variantes pour obtenir directement le « X » : en utilisant une liste déroulante (ou en saisissant directement le numéro du jour de la semaine), on obtient le numéro de colonne, par exemple en cellule P2.
1) la colonne B (B3) contient la lettre X. En colonne A (A3) : =RECHERCHEV(
B3 ; B3:K3 ;3+ $P$2 ). il suffit de lui faire rechercher le contenu de B3 dans la plage B3:K3 sur une seule ligne. Il le trouve
(évidemment) et il retourne le contenu de la colonne indiquée en P3, numéro augmenté du décalage de colonne (le « compteur » sera incrémenté selon la colonne A).
2) En colonne A (A3) :
=CHOISIR( $P$2 ;E3;F3;G3;H3;I3;J3;K3)
. Il suffit de lui faire choisir le n ième argument de la liste (correspondant au 7 jours).
3) En colonne A (A3) : =CHOISIR(1;INDIRECT(ADRESSE(LIGNE();COLONNE()+
$P$2 +2))) . Il choisit le premier de la bonne cellule dont l’adresse est définie par la ligne en cours et la colonne en cours décalée du nombre de jours plus le décalage du tableau par rapport à la position de la formule.
1 Rappel : « jour » correspond à la la cellule « O2 » dans cet exemple.
Fonctions_Avancees_Recherche.odt -
Retour au Sommaire
8 / 15
fr.OpenOffice.org
6 Recherche multi-critères
6.1 Dans une table
Énoncé de l’exemple
Nous souhaitons réaliser des factures. Prenons en compte deux contraintes :
–
–
Les factures doivent être conservées pendant un an,
Le tarif change en cours d’année.
Cala nous amène à la création des tables suivantes
La plage nommées « dmp » (dates matières premières) contient « D5:I6 » Elle contient les dates
(1er jour d’application du tarif) et un numéro correspondant au nunméro de colonne de la table suivante. C’est ce numéro qui sera retourné pour obtenir la bonne colonne du tarif.
La plage nommées « matprem » (matières premières) contient « A7:I14 »
Réalisation
L’aspect de la facture sera le suivant
La date est saisie en E2,
Les colonnes A et D serviront pour la saisie.
Colonne B (B7) : =RECHERCHEV(
A7 ; matprem ;2;0). Pour gérer les cellules vides en colonne A, elle devient : =SI(ESTVIDE(
A7 );".";RECHERCHEV( A7 ; matprem ;2;0)).
Fonctions_Avancees_Recherche.odt -
Retour au Sommaire
9 / 15
fr.OpenOffice.org
Colonne C (C7) : =RECHERCHEV(
A7 ; matprem ;3;0) qui devient
=SI(ESTVIDE( A7 );".";RECHERCHEV( A7 ; matprem ;3;0))
Remarques : Le point « ...(
A7 );".";RE... » peut être supprimé. Il est uniquement utilisé à titre personnel pour la mise au pont des exercices de façon à « voir » les recopies de formules.
La similitude des deux formules permet la recopie (par un « copier-coller), et non pas « en tirant » sur la poignée de recopie).
La mise au point de formules peut se faire sans le test SI(ESTVIDE(A7). Il sera ajouté par un « copiercoller) ».
Colonne E (E7) : =RECHERCHEV(
A24 ; matprem ;RECHERCHEH( $E$2 ;dmp;2)) ou
=SI(ESTVIDE( A24 );".";RECHERCHEV( A24 ; matprem ;RECHERCHEH($E$2;dmp;2)))
La partie RECHERCHEH($E$2;dmp;2) fournit le numéro de colonne à utiliser dans la table « matprem » pour la fonction principale. Dans l’exemple, elle retourne la valeur 6 (cellule F6). Il dépend donc de la date saisie en E2.
6.2 Dans différentes tables
Lorsque la situation est complexe, il devient parfois nécessaire de répartir les données dans différentes tables – de structure parfaitement identique. Parfois, il s’agit d’aller chercher sur différentes feuilles. C’est alors la table matrice qui va changer. On ne peut pas alors utiliser une référence de cellule. Il faut utiliser son contenu comme une référence. c’est le rôle de la fonction
« Indirect ».
6.2.a Notions de base de la fonction Indirect.
Je souhaite faire la somme de la colonne A ou B, pour un nombre de lignes variable.
Les données sont réparties de B2 à C8,
Le nom de la colonne est indiqué en B10,
Le nombre de lignes saisi en B10
La plage à utiliser est définie automatiquement en B12 par la formule : =
B10 &"2:"& B10 &1+ B11
1 .
Attention : dans la fonction Indirect, OOo accepte les noms de feuilles (ex : Tables.D8:D9), mais pas les noms de plage.
1 L’esperluette (« & ») permet la concaténation. Le 1 de « 1+B11 » permet de retirer 1 au numéro de départ pour commencer à la ligne 2 lorsque B11 vaut 1.
Fonctions_Avancees_Recherche.odt -
Retour au Sommaire
10 / 15
fr.OpenOffice.org
Soient les feuilles « Toto » et « Titi ». Selon l’exemple ci-dessus, pour obtenir le valeur de la cellule
H40 de la feuille correspondant, on indique en F24 le nom de la feuille, et en F25 la formule :
=INDIRECT( F24 &".h40").
L’utilisation des listes déroulantes permet de trouver facilement le bon nom de feuille ou de table matrice.
Cette fonction remplace alors le nom de la table matrice .
6.2.b Application multi-table
Énoncé
On désire établir le tarif de différentes catégories de produits. Chaque produits dispose de 3 tarifs possibles. Les données sont stockées dans des tables différentes.
Les tables sont réparties comme indiqué en F3:G5. C’est cette table qui permet d’établir la liste déroulante « Catégorie ». La table J3:J5 permet d’établir la liste déroulante « Tarif ».
Le fruit de la recherche est affiché en B7:C12.
Réalisation
Le contrôle affiché sur la cellule B3 permet d’obtenir l’information nécessaire à la recherche de la plage de cellules correspondant. A des fins pédagogiques, il est affiché en C3. Il peut être soit affiché en B3, sur une ligne masquée, de la couleur du fond de la cellule.
Le contrôle destiné au tarif retourne directement le numéro d’ordre en C4.
Fonctions_Avancees_Recherche.odt -
Retour au Sommaire
11 / 15
fr.OpenOffice.org
Contrôle « Catégorie » Contrôle «Tarif»
Cellule D3 : =RECHERCHEV(
C3 ;F3:G5;2;0). Retourne la plage de cellules à utiliser comme table matrice.
Colonne B (B7) : RECHERCHEV(
$A7 ;INDIRECT($D$3);2) ou
=SI( RECHERCHEV( $A7 ;INDIRECT( $D$3 );1) = $A7 ; RECHERCHEV( $A7 ;INDIRECT( $D$3 );2) ; "" )
On recherche le « A e » élément de la table définie en D3.
Pour le tarif, il suffit de reprendre la même formule, mais la colonne est décallée de « C4 ».
=SI( RECHERCHEV( $A7 ;INDIRECT( $D$3 );1) = $A7 ; RECHERCHEV( $A7 ;INDIRECT( $D$3 );2+ $C$4 ) ; "" )
7 Applications diverses
7.1 Un tri dynamique
Ce tri ne fonctionne que sur des valeurs numériques. La méthode consiste à déterminer le rang de la valeur dans la liste et à placer ce résultat à gauche de la liste de valeurs.
Il ne reste plus qu’a reprendre les valeurs dans l’ordre souhaité (indiqué en colonne D) avec la fonction recherche.
Colonne A (A3) : =RANG(
B3 ; B$3:B$8 ;1) La valeur 1 en 3e argument (type) permet d’obtenir un résultat par ordre croissant.
La colonne B correspond aux valeurs à trier.
La colonne D est une liste incrémentée.
Colonne E (E3) : =RECHERCHEV(
D3 ; $A$3:$B$8 ;2;0). Les valeurs (2e colonne) sont récupérées dans une liste non triée.
7.2 Extraction dynamique
Énoncé
Colonne B : saisie des noms à extraire
Colonne C : critère d’extraction – 0 : non adhérent – 1 : adhérent à extraire.
Fonctions_Avancees_Recherche.odt -
Retour au Sommaire
12 / 15
Colonne G : Résultat.
fr.OpenOffice.org
Réalisation
Colonne A (A4) : =SI(
C4 =1; A3 +1; A3 ). On incrémente un compteur lorsqu’il s’agit d’un adhérant.
Colonne F : Liste incrémentée.
Colonne G (G4) : =RECHERCHEV(
F4 ; A$4:B$12 ;2;0) Il suffit de rechercher le numéro qui est en F4 dans la table matrice des noms (non triée pour trouver la 1ere correspondance).
La formule complète =SI(ESTNA(RECHERCHEV(
F4 ; A$4:B$12 ;2;0));"";RECHERCHEV( F4 ; A$4:B$12 ;2;0)) fournit un exemple sans message d’erreur.
7.3 Ventilation automatique
Énoncé
L’objectif de cette application est de ventiler des données vers différentes feuilles (ou liste sur une même feuille). Par exemple des élèves à répartir par classes. Cette feuille est nommée « eleves »
La table B3:D9 contient des données saisies (classe, nom, prénom).
Réalisation
En premier lieu, colonnes E à G, on crée un compteur par classe, qui s’incrémente lorsque l'élève fait partie de la classe en question. Le nom de la classe est saisi en ligne 1.
Colonne E (E3) : =SI(
$B3 = E$1 ; E2 +1; E2 ) Noter l’utilisation de références mixtes pour la recopie (vers le bas, et colonnes F et G.
Fonctions_Avancees_Recherche.odt -
Retour au Sommaire
13 / 15
fr.OpenOffice.org
Colonne I : Il s’agit d’une simple liste incrémentée destinée à situer le numéro de ligne pour la recherche suivante (dans la table E1:G9).
Colonne J (J3) : =RECHERCHEH(
B3 ; $E$1:$G$9 ; I3 +2). On récupère le rang occupé par l’élève dans la bonne cellule de la table, colonne correspondant à la classe (indiquée en B), ligne définie en I, +2 car la table matrice commence en ligne 1 et les données à retourner en ligne 3.
Colonne A (A3) : =
B3 & J3
. Il suffit de concaténer la classe et le rang pour obtenir un code unique pour la recherche.
Variante : en numérotant les cellules E2 à G2 respectivement 1, 2, 3, il est possible d’utiliser
= B3 &CHOISIR(RECHERCHEH( B3 ; $E$1:$G$2 ;2;0); E3 ; F3 ; G3 ) .
Le numéro retourné par la fonction recherche permet de d’obtenir directement la bonne donnée parmi les 3 cellules possibles. Attention dans ce cas, pour E3, F3, G3 de ne pas utiliser la ligne 2. (=SI(
$B3 = E$1 ;1;0) ; la ligne 4 est alors différente =SI(
$B4 = E$1 ; E3 +1; E3 )).
La ligne 12 soit reprend la ligne 9 soit la valeur maximum de la colonne (utile pour les classes)
Pour chaque classe, la feuille est similaire.
La cellule C1 contient la classe
La cellule c2 =RECHERCHEH(
$C$1 ; eleves.E1:G12 ;12) contient le nombre d’élèves afin d’éviter les messages d’erreur.
Colonne B (B3) : =SI(
A3 <= $C$2 ;RECHERCHEV( $C$1 & A3 ; $eleves.$A$2:$E$9 ;3;0);"")
La valeur à rechercher est
$C$1 & A3
(la valeur « A1 » ici) sur la feuille eleves.
Fonctions_Avancees_Recherche.odt -
Retour au Sommaire
14 / 15
fr.OpenOffice.org
8 Crédits
Auteur : Jean-François Delaroque
Remerciement : Jean-François Nifenecker
Intégré par : Tony Galmiche
Contacts : Projet Documentation OpenOffice.org -
fr.OpenOffice.org
Traduction :
Historique des modifications :
Version Date
1.0
11/10/06 Création
Commentaire
9 Licence
Appendix
Public Documentation License Notice
The contents of this Documentation are subject to the Public Documentation License
Version 1.0 (the "License"); you may only use this Documentation if you comply with the terms of this
License. A copy of the License is available at
http://www.openoffice.org/licenses/PDL.html
.
The Original Documentation is Fonctions_Avancees_Recherche.odt . The Initial
Writer of the Original Documentation is Jean-François Delaroque Copyright © 2006 [Insert year(s)].
All Rights Reserved. (Initial Writer contact(s): contact@interfleuron.fr Insert hyperlink/alias]).
Contributor(s): ______________________________________.
Portions created by ______ are Copyright ©_________[Insert year(s)]. All Rights Reserved.
(Contributor contact(s):________________[Insert hyperlink/alias]).
NOTE: The text of this Appendix may differ slightly from the text of the notices in the files of the Original Documentation. You should use the text of this Appendix rather than the text found in the Original Documentation for Your Modifications.
Fonctions_Avancees_Recherche.odt -
Retour au Sommaire
15 / 15
